Подключение DFPlayer Mini MP3 к Arduino

DFPlayer Mini MP3 Player для Arduino — это небольшой и недорогой MP3-модуль с упрощенным выходом непосредственно на динамик. Модуль можно использовать как отдельный модуль с подключенной батареей, динамиком и кнопками или использовать в сочетании с Arduino UNO или любым другим модулем с возможностями RX/TX.

Спецификация

поддерживаемые частоты дискретизации (кГц): 8/11,025/12/16/22,05/24/32/44,1/48
24-битный выход ЦАП, поддержка динамического диапазона 90 дБ, поддержка SNR 85 дБ
полностью поддерживает файловую систему FAT16, FAT32, максимальная поддержка 32G TF-карты, поддержка 32G U-диска, 64M байт NORFLASH
различные режимы управления, режим управления вводом-выводом, последовательный режим, режим управления кнопкой AD
функция ожидания рекламного звука, музыку можно приостановить. когда реклама закончилась музыка продолжает играть
аудиоданные отсортированы по папкам, поддерживает до 100 папок, каждая папка может содержать до 255 песен
30 уровней громкости, 6 уровней эквалайзера

Приложение

Голосовая трансляция автомобильной навигации;
Автоинспекции, голосовые подсказки пунктов взимания платы;
Железнодорожный вокзал, голосовые подсказки проверки безопасности автобусов;
Электричество, связь, голосовые подсказки финансового бизнес-зала;
Транспортное средство в и из канала убедитесь, что голосовые подсказки;
Голосовые подсказки канала пограничного контроля общественной безопасности;
Многоканальное голосовое оповещение или голосовое руководство по эксплуатации оборудования;
голосовые уведомления о безопасном вождении электрического туристического автомобиля;
Сигнализация отказа электромеханического оборудования;
Голосовые подсказки пожарной сигнализации;
Автоматическое вещательное оборудование, регулярное вещание.

Пин-карта

Режим работы

Последовательный режим

Поддержка режима асинхронной последовательной связи через последовательную отправку команд ПК Стандарт связи: 9600 бит/с Биты данных: 1 Проверка: нет Управление потоком: нет

Режим AD KEY

Мы используем ключи модуля AD вместо традиционного метода подключения матричной клавиатуры, чтобы воспользоваться преимуществами все более мощной функциональности MCU AD. Конфигурация нашего модуля по умолчанию 2 порта AD, распределение сопротивления 20 клавиш.

Режим ввода/вывода

Вот самый простой способ использования этого модуля.

Примечание: короткое нажатие означает предыдущий/следующий, а долгое нажатие означает vol-, vol +

Схема подключения к Arduino

Примечание. Для простого использования верхняя диаграмма готова, но если вы обнаружите, что шум довольно громкий, вы можете подключить резистор 1 кОм к выводу TX.

Скопируйте свой mp3 на карту micro SD

Примечание . Порядок копирования mp3 на карту micro SD влияет на порядок воспроизведения mp3, что означает, что функция play(1) будет воспроизводить первый mp3, скопированный на карту micro SD.

Библиотека Arduino для DFPlayer Mini создана для того, чтобы упростить вам работу. Подключите оборудование, как показано на рисунке выше, и поиграйте с примером кода. Скачать последнюю библиотеку можно здесь

Пример кода "FullFunction", включая все функции. Пожалуйста, внимательно прочитайте комментарии и документы

/***************************************************
DFPlayer - A Mini MP3 Player For Arduino ampertok.ru
***************************************************
В этом примере показаны все функции библиотеки для DFPlayer.
Смотрите  для деталей.
Все вышеперечисленное может быть включено в любое перераспределение
Этот код протестирован на платах Arduino Uno, Leonardo, Mega.
****************************************************/

#include "Arduino.h"
#include "SoftwareSerial.h"
#include "DFRobotDFPlayerMini.h"

SoftwareSerial mySoftwareSerial(10, 11); // RX, TX
DFRobotDFPlayerMini myDFPlayer;
void printDetail(uint8_t type, int value);

void setup()
{
  mySoftwareSerial.begin(9600);
  Serial.begin(115200);

  Serial.println();
  Serial.println(F("DFRobot DFPlayer Mini Demo"));
  Serial.println(F("Initializing DFPlayer ... (May take 3~5 seconds)"));

  if (!myDFPlayer.begin(mySoftwareSerial)) {  //Используйте SoftwareSerial для связи с mp3.
    Serial.println(F("Unable to begin:"));
    Serial.println(F("1.Please recheck the connection!"));
    Serial.println(F("2.Please insert the SD card!"));
    while(true);
  }
  Serial.println(F("DFPlayer Mini online."));

  myDFPlayer.setTimeOut(500); //Установите время ожидания последовательной связи 500 мс

  //----Set volume----
  myDFPlayer.volume(10);  //Установите значение громкости (0~30).
  myDFPlayer.volumeUp(); //Увеличение громкости
  myDFPlayer.volumeDown(); //Уменьшение громкости

  //----Set different EQ----
  myDFPlayer.EQ(DFPLAYER_EQ_NORMAL);
//  myDFPlayer.EQ(DFPLAYER_EQ_POP);
//  myDFPlayer.EQ(DFPLAYER_EQ_ROCK);
//  myDFPlayer.EQ(DFPLAYER_EQ_JAZZ);
//  myDFPlayer.EQ(DFPLAYER_EQ_CLASSIC);
//  myDFPlayer.EQ(DFPLAYER_EQ_BASS);

  //----Установите устройство, мы используем SD по умолчанию----
//  myDFPlayer.outputDevice(DFPLAYER_DEVICE_U_DISK);
  	myDFPlayer.outputDevice(DFPLAYER_DEVICE_SD);
//  myDFPlayer.outputDevice(DFPLAYER_DEVICE_AUX);
//  myDFPlayer.outputDevice(DFPLAYER_DEVICE_SLEEP);
//  myDFPlayer.outputDevice(DFPLAYER_DEVICE_FLASH);

  //----Mp3 control----
//  myDFPlayer.sleep();     //сон
//  myDFPlayer.reset();     //сброс
//  myDFPlayer.enableDAC();  //Включить встроенный DAC
//  myDFPlayer.disableDAC();  //Отключить встроенный DAC
//  myDFPlayer.outputSetting(true, 15); //настройка выходного сигнала, включите выходной сигнал и установите коэффициент усиления на 15

  //----Mp3 play----
  myDFPlayer.next();  //Воспроизвести следущий трек
  delay(1000);
  myDFPlayer.previous();  //Воспроизвести предыдущий трек
  delay(1000);
  myDFPlayer.play(1);  //Воспроизвести первую композицию
  delay(1000);
  myDFPlayer.loop(1);  //Зациклить первую композицию
  delay(1000);
  myDFPlayer.pause();  //Пауза
  delay(1000);
  myDFPlayer.start();  //запустите с паузы
  delay(1000);
  myDFPlayer.playFolder(15, 4);  //воспроизведение определенного mp3 на SD:/15/004.mp3; Имя папки(1~99); Имя файла(1~255)
  delay(1000);
  myDFPlayer.enableLoopAll(); //зациклите все mp3-файлы.
  delay(1000);
  myDFPlayer.disableLoopAll(); //остановить цикл всех mp3-файлов.
  delay(1000);
  myDFPlayer.playMp3Folder(4); //воспроизведение определенного mp3 на SD:/MP3/0004.mp3; Имя файла(0~65535)
  delay(1000);
  myDFPlayer.advertise(3); //объявите определенный mp3 на SD:/ADVERT/0003.mp3; Имя файла(0~65535)
  delay(1000);
  myDFPlayer.stopAdvertise(); //прекратить объявление
  delay(1000);
  myDFPlayer.playLargeFolder(2, 999); //воспроизведение определенного mp3 на SD:/02/004.mp3; Имя папки(1~10); Имя файла(1~1000)
  delay(1000);
  myDFPlayer.loopFolder(5); //зациклите все mp3-файлы в папке SD:/05.
  delay(1000);
  myDFPlayer.randomAll(); //Случайное воспроизведение всего mp3.
  delay(1000);
  myDFPlayer.enableLoop(); //включить цикл.
  delay(1000);
  myDFPlayer.disableLoop(); //отключить цикл.
  delay(1000);

  //----Прочитайте информацию----
  Serial.println(myDFPlayer.readState()); //считывание состояния mp3
  Serial.println(myDFPlayer.readVolume()); //считывание текущего объема
  Serial.println(myDFPlayer.readEQ()); //считывание настройки эквалайзера
  Serial.println(myDFPlayer.readFileCounts()); //считайте все количество файлов на SD-карте
  Serial.println(myDFPlayer.readCurrentFileNumber()); //считывание текущего номера файла воспроизведения
  Serial.println(myDFPlayer.readFileCountsInFolder(3)); //считайте количество файлов в папке SD:/03
}

void loop()
{
  static unsigned long timer = millis();

  if (millis() - timer > 3000) {
    timer = millis();
    myDFPlayer.next();  //Воспроизводите следующий mp3 каждые 3 секунды.
  }

  if (myDFPlayer.available()) {
    printDetail(myDFPlayer.readType(), myDFPlayer.read()); //Распечатайте подробное сообщение из DFPlayer для обработки различных ошибок и состояний.
  }
}

void printDetail(uint8_t type, int value){
  switch (type) {
    case TimeOut:
      Serial.println(F("Time Out!"));
      break;
    case WrongStack:
      Serial.println(F("Stack Wrong!"));
      break;
    case DFPlayerCardInserted:
      Serial.println(F("Card Inserted!"));
      break;
    case DFPlayerCardRemoved:
      Serial.println(F("Card Removed!"));
      break;
    case DFPlayerCardOnline:
      Serial.println(F("Card Online!"));
      break;
    case DFPlayerPlayFinished:
      Serial.print(F("Number:"));
      Serial.print(value);
      Serial.println(F(" Play Finished!"));
      break;
    case DFPlayerError:
      Serial.print(F("DFPlayerError:"));
      switch (value) {
        case Busy:
          Serial.println(F("Card not found"));
          break;
        case Sleeping:
          Serial.println(F("Sleeping"));
          break;
        case SerialWrongStack:
          Serial.println(F("Get Wrong Stack"));
          break;
        case CheckSumNotMatch:
          Serial.println(F("Check Sum Not Match"));
          break;
        case FileIndexOut:
          Serial.println(F("File Index Out of Bound"));
          break;
        case FileMismatch:
          Serial.println(F("Cannot Find File"));
          break;
        case Advertise:
          Serial.println(F("In Advertise"));
          break;
        default:
          break;
      }
      break;
    default:
      break;
  }
}

Примечание. Имя папки должно быть mp3 и находиться в корневом каталоге SD-карты, а имя файла mp3 должно состоять из 4 цифр, например, «0001.mp3», и находиться в папке mp3. Если вы хотите назвать его как на английском, так и на китайском языке, вы можете добавить его после номера, например, «0001hello.mp3» или «0001后来.mp3».

Теги: #модули

3634

6 Января, 2024

Комментарии

Ваш комментарий будет первым